Lists & arrays#

-- `List<T>` is V3's typed sequence. The element type must be a scalar
-- (`int`, `num`, `word`, `bool`) or the name of a shape. Nesting is not
-- allowed: there is no `List<List<int>>`.
shape Contact {
    tag: word
}

-- A List may be a parameter and a return type. It may NOT be a shape
-- field: that reports "V3 owned shape fields do not yet support List
-- values".
task count_all(items: List<word>) -> int {
    give back items.length()
}

task first_three() -> List<int> {
    give back [1, 2, 3]
}

task main() -> void {
    -- An array literal infers List<T> from its elements.
    pilot names: List<word> = ["Takeru", "Meiya", "Sumika"]
    say word_from_int(names.length())
    say names[1]

    -- Indexed assignment requires `pilot mut`.
    pilot mut scores: List<int> = [10, 20, 30]
    scores[0] = 99
    say word_from_int(scores[0])

    -- Every scalar element type works.
    pilot ratios: List<num> = [1.5, 2.5]
    say format_num(ratios[1])

    pilot flags: List<bool> = [true, false]
    say word_from_bool(flags[0])

    -- Shapes too, and field access chains off the element.
    pilot contacts: List<Contact> = [Contact { tag: "BETA-1" }]
    say contacts[0].tag

    -- List::filled(value, count) builds a pre-populated list.
    pilot zeros: List<int> = List::filled(0, 4)
    say word_from_int(zeros.length())

    -- Passed to a task, and returned from one.
    say word_from_int(count_all(names))
    say word_from_int(first_three()[2])

    -- Lists grow as of v0.14.2. Mutating methods need `pilot mut`.
    pilot mut queue: List<int> = List::new()
    queue.push(10)
    queue.push(20)
    queue.push(30)
    say word_from_int(queue.length())
    say word_from_int(queue.pop())      -- 30, removed and returned
    say word_from_int(queue.length())
    say word_from_int(queue.capacity()) -- starts at 8, doubles as needed
    queue.reserve(64)
    say word_from_int(queue.capacity())
    queue.clear()
    say word_from_int(queue.length())

    -- Iterate with an index; there is no `for each`.
    pilot mut i: int = 0
    repeat names.length() times {
        say names[i]
        i += 1
    }
}

3
Meiya
99
2.5
true
BETA-1
4
3
3
3
30
2
8
64
0
Takeru
Meiya
Sumika

-- V3 arrays are runtime handles of `word` elements, addressed by an
-- `int` handle. Store other types by converting them to `word`.
task main() -> void {
    pilot xs: int = array_new()

    array_push(xs, "alpha")
    array_push(xs, "bravo")
    array_push(xs, "charlie")

    say word_from_int(array_len(xs))
    say array_get(xs, 0)
    say array_get(xs, 2)

    array_set(xs, 1, "BRAVO")
    say array_get(xs, 1)

    -- Iterate with an index and a counted loop.
    pilot mut i: int = 0
    repeat array_len(xs) times {
        say array_get(xs, i)
        i += 1
    }

    array_release(xs)
}

3
alpha
charlie
BRAVO
alpha
BRAVO
charlie

-- An array literal infers `List<T>` from its elements. Numbers stay
-- numbers -- there is no need to convert them to `word` any more.
--
-- The older untyped `array_*` handle still exists alongside it; see
-- arrays.html for when each one applies.
task main() -> void {
    pilot names: List<word> = ["Takeru", "Meiya", "Sumika"]
    say word_from_int(names.length())
    say names[1]

    pilot numbers: List<int> = [3, 1, 2]
    say word_from_int(numbers.length())
    say word_from_int(numbers[0])

    -- The array_* builtins accept a List<word> as well as a raw handle.
    say word_from_int(array_len(names))
    say array_get(names, 2)

    -- std/algorithm.fk tasks are declared with `handle: int`, so they take
    -- only the legacy handle. Build one with array_new() to use them.
    pilot h: int = array_new()
    array_push(h, word_from_int(3))
    array_push(h, word_from_int(1))
    array_push(h, word_from_int(2))

    array_sort_int(h)
    say array_join(h, ",")
    say word_from_int(array_sum_int(h))
    say word_from_int(array_max_int(h))
    say word_from_int(array_binary_search_int(h, 3))

    array_reverse(h)
    say array_join(h, "|")
    say word_from_bool(array_contains(h, "2"))

    array_release(h)
}

3
Meiya
3
3
3
Sumika
1,2,3
6
3
2
3|2|1
true